perm filename ONCE[KA,SYS] blob
sn#227166 filedate 1976-07-27 generic text, type C, neo UTF8
COMMENT ⊗ VALID 00015 PAGES
C REC PAGE DESCRIPTION
C00001 00001
C00003 00002 BEGIN ONCE ONLY CODE
C00005 00003 SETUP LOCATIONS 40 THRU 61
C00007 00004 ONCE ONLY CODE - OPERATOR SETUP DIALOGUE
C00013 00005 FALL THROUGH
C00018 00006 HERE IS WHERE P2 STARTS
C00020 00007 DATLOP, TIMLOP GET DATE AND TIME FROM CTY
C00024 00008 IFN 0*FTDISK,< REFRESH DIALOGUE
C00026 00009 ROUTINE TO READ A LINE FROM OPERATORS CONSOLE
C00028 00010 ROUTINE TO TYPE A LINE ON OPERATOR CONSOLE
C00031 00011 CONSTANTS AND PUSH DOWN LIST
C00032 00012 IFKL10,< LOAD CACHE REFILL ALGORITHM
C00038 00013 206 RESTARTS -- USER AND EXEC MODE
C00045 00014 PUNCH SYSTEM LOADER WITH CURRENT LOC OF SYSTEM ON LIBRASCOPE
C00048 00015 START - USER MODE 200 STARTUP
C00050 ENDMK
C⊗;
BEGIN ONCE ONLY CODE
SUBTTL ONCE 1969 JAN 29 ;WITH MODS FOR DSKSER -RAS.
↑UUOFLK←←UUOLNK ;FIX THIS UP NOW (AT END OF SYSTEM)
;THIS PAGE IS THE EXIT FROM ONCE!
LINKSR: MOVE TAC,[PUSHJ P,OUTCHS] ;DWP FOR TTYSER
MOVEM TAC,CONTYO ;DWP
MOVE TAC,[PUSHJ P,GETCHR]
MOVEM TAC,CONTYI ;DWP
NOKL10,<
LINKS1: CONSZ CTY,20 ;WAIT FOR CTY TO FINISH TYPEOUT
JRST LINKS1
>;NOKL10
MOVE AC1,ONCE ;SAVE RETURN ADDR
IFN FTDDT,<
;SAVE SYMBOLS FOR DDT. DDTSYM IS SET UP AT LOAD TIME.
HLRO TAC1,DDTSYM ;-LENGTH OF SYMBOL TABLE
MOVNS TAC1 ;MAKE IT +
HRLZ TAC,DDTSYM ;SYMTAB BEGINS HERE
HRRI TAC,BLTBEG ;MOVE IT TO HERE
BLT TAC,BLTBEG-1(TAC1) ;THERE IT WENT
MOVEI TAC,BLTBEG ;TELL EXEC DDT WHERE
HRRM TAC,DDTSYM ;IT LOOKS AT 36
MOVEI TAC,BLTBEG(TAC1) ;END OF SYMBOL TABLE.
>;FTDDT
IFE FTDDT,<
MOVEI TAC,BLTBEG
>
MOVEM TAC,SYSSIZ ;IS TOP OF SYSTEM.
JRST @AC1 ;RETURN TO SYSINI
LIT
↑↑BLTBEG←←. ;FIRST LOCATION OF ONCE THAT'S CLOBBERED
;SETUP LOCATIONS 40 THRU 61
;P1 TRAP LOCATIONS
LOC40: 0 ;UUO STORED HERE
JSR UUO0 ;UUO TRAPS HERE
JSR CH1
JSR PIERR
JSR CH2
JSR PIERR
JSR CH3
JSR PIERR
JSR CH4
JSR PIERR
JSR CH5
JSR PIERR
JSR CH6
JSR PIERR
JSR CH7
JSR PIERR
NOKL10,<
0 ;ILLEGAL INSTRUCTION STORED HERE
JSR UUO2 ;ILLEGAL INSTRUCTION TRAPS HERE
>;NOKL10
IFN FTPAGER,<
P2GLOC: JSR P2GINT ;LOCATION 170
PSB⊗-9 ;BYTE (4)0 (3)ALR (11)UBR (5)ACBR (2)0 (11)MBR
700000,, ;BYTE (9)AGER (1)0 (26)PUR
>;FTPAGER
IFN FTDDT,<
DDXLOC: SYMLOC ;AT LOC 162 - POINTERS INTO DDT FOR UEDDT
DDTXCOR
DDTSWP
DDTA
>
;P2 TRAP LOCATIONS
P2LOC40:
0 ; P2 UUO'S COME HERE
JSR UUO0+P2PID
JSR P2CH1
JSR PIERR+P2PID
JSR P2CH2
JSR PIERR+P2PID
JSR P2CH3
JSR PIERR+P2PID
JSR P2CH4
JSR PIERR+P2PID
JSR P2CH5
JSR PIERR+P2PID
JSR P2CH6
JSR PIERR+P2PID
JSR P2CH7
JSR PIERR+P2PID
0 ;P2 UNDEF OPCODES COME HERE
JSR UUO2+P2PID
;ONCE ONLY CODE - OPERATOR SETUP DIALOGUE
↑ONCE: 0 ;JSR HERE FROM SYSINI
SKIPP1 ;SKIP IF THIS IS P1
JRST SYSDSP+4 ;THIS IS P2. GET OUT!
MOVSI TAC,40000
IFE PRCONF-2,< MOVEM TAC,141 ;KLUDGE TO GET P2 INTO EXEC MODE >;P2=KA10
IFL PRCONF-2,< MOVEM TAC,41 ;KLUDGE TO GET P2 INTO EXEC MODE >;P2=PDP6
SETZM P2NUM ;P2 ISN'T THERE YET
MOVE P,[-ONCEPN,,ONCEPD-1]
MOVEI IOS,0 ;MAKE SURE SCNSER WILL TYPE ;JS
MOVE TAC,[IDPB TEM,DAT] ;DWP FOR TTYSER
MOVEM TAC,CONTYO ;DWP
MOVE TAC,[ILDB TEM,DAT]
MOVEM TAC,CONTYI ;DWP
MOVE DAT,LINEP ;SETUP LINE BYTE POINTER
PUSHJ P,CRLF
MOVEI TAC,CONFIG
PUSHJ P,CONMES
PUSHJ P,CRLF
IFE FTDDT,<
MOVEI TAC,NDDTM
PUSHJ P,CONMES
>;FTDDT
PUSHJ P,OPOUT ;TYPE IT OUT NOW
SETZM DETFLG ;SETUP LOW CORE LOCATIONS
NOKL10,<
MOVEI TAC,652237 ;PI CONO
HRRM TAC,PICON
MOVEI TAC,140
MOVEM TAC,UUOLOC+P1PID
MOVE TAC,[LOC40,,140]
BLT TAC,161 ;PUT INTERRUPT LOCATIONS IN RIGHT PLACE
>;NOKL10
IFKL10,<
MOVEI TAC,032237 ;KL10 PI CONO
HRRM TAC,PICON
CONI KLPAG,TAC1
ANDI TAC1,777
LSH TAC1,=9 ;EPT ADDRESS
MOVEI TAC,KLUPT+424 ;IMAGE OF MUUO STORED HERE
MOVEM TAC,UUOLOC+P1PID
IFE PRCONF-2,<
MOVE TAC,[JSR KLLUUT] ;LUUO TRAP FOR P1,
MOVEM TAC,41 ;ONLY IF P2 IS A KA10
>;PRCONF=2
MOVE TAC,[LOC40+2,,42] ;(EPT LOC 40/41 AREN'T USED)
ADDI TAC,(TAC1) ;OFFSET DESTINATION INTO THE EPT
BLT TAC,57(TAC1) ;PUT INTERRUPT LOCATIONS IN RIGHT PLACE
MOVSI TAC,(<JFCL>)
MOVEM TAC,421(TAC1) ;EXEC ARITHMETIC OVERFLOW TRAP INSTR.
MOVEM TAC,423(TAC1) ;EXEC TRAP-3 TRAP INSTR.
MOVEM TAC,KLUPT+421 ;USER AROV TRAP INSTR.
MOVEM TAC,KLUPT+423 ;USER TRAP-3 INSTR.
MOVE TAC,[JSR EPDLOV]
MOVEM TAC,422(TAC1) ;EXEC PDLOV TRAP INSTR.
MOVE TAC,[.TRAP 2,] ;
MOVEM TAC,KLUPT+422 ;USER PDLOV TRAP INSTR.
MOVE TAC,[PCU,,KLUUOH] ;THE UUO TRAP HANDLER. PREV CONTEXT USER
MOVEM TAC,KLUPT+430
MOVE TAC,[KLUPT+430,,KLUPT+431]
BLT TAC,KLUPT+437
MOVE TAC,[PCU,,TRPUUO]
MOVEM TAC,KLUPT+435 ;.TRAP WILL TRAP TO TRPUUO
MOVEM TAC,KLUPT+437
MOVE TAC,[PCU,,KLPFTR] ;PAGE FAIL TRAP HANDLER
MOVEM TAC,KLUPT+KLPFNP
PUSHJ P,SETCRA ;SETUP CACHE REFILL ALGORITHM
>;IFKL10
JRST MPXLOD ;LOAD MAPPIPLEXOR MICROCODE
LOC <.+777>∧777000 ;NEXT PAGE BOUNDARY
MPXMIC:
.INSERT MPX.INS[MPX,JBR] ;GET MICROCODE
MPXLOD: MOVEI TAC,MPXMIC
LSH TAC,-9 ;PHYSICAL PAGE NUMBER OF MICROCODE
HRLI TAC,400000
CONSZ MPX,MBUSY ;MAKE SURE MPX IS NOT BUSY
JRST .-1
CONO MPX,MRESET!MENBPI ;ZAP HIM GOOD
CONSZ MPX,MBUSY
JRST .-1 ;WAIT TILL DONE CLEARING RAMS
DATAO MPX,TAC ;START MICROCODE LOAD
CONSZ MPX,MBUSY ;WAIT FOR MICROCODE LOAD TO FINISH
JRST .-1
IFN FTDDT,<
MOVE TAC,[DDXLOC,,162]
BLT TAC,165 ;SETUP FOR UEDDT
>;FTDDT
SETZM TIME
SETZM THSDAT
SETOM P1NUM ;TELL P2 THAT P1 IS ALIVE!
MOVE TAC,[JSR P2START-1]
MOVEM TAC,SYSDSP+4 ;TIME TO LET P2 GO
IFL PRCONF-2,< MOVEM TAC,41 ;PERHAPS FROM HERE >;P2=PDP6
IFE PRCONF-2,< MOVEM TAC,141 ;PERHAPS FROM HERE >;P2=KA10
NOKL10,< ;KL10 DOESN'T HAVE A PTR
CONO PTR,120 ;THIS IS THE PTR REVERSE HACK
PTREV0: MOVEI TAC1,=40 ;TWO EXTRA INCHES AFTER WE STOP SEEING BITS
PTREV1: CONSZ PTR,20 ;WAIT FOR ¬BUSY
JRST .-1
DATAI PTR,TAC
ANDI TAC,300
CAIN TAC,200 ;SKIP IF ¬ A BINARY TAPE
JRST PTREV0 ;WE SAW A BIT. SET COUNT TO MAX
SOJG TAC1,PTREV1 ;LOOP FOR A WHILE AFTER WE SEE THE LAST BIT
>;NOKL10
;FALL THROUGH
;FALL THROUGH
MOVEI TAC,100000 ;IS P2 STARTED?
SKIPN TAC1,P2NUM
SOJGE TAC,.-1
JUMPN TAC1,P1G1 ;YES. SKIP CTY TYO
MOVE DAT,LINEP ;ASK OPERATOR TO START UP P2
MOVEI TAC,[ASCIZ /Start other processor at /]
PUSHJ P,CONMES
MOVEI TAC,SYSDSP+4
PUSHJ P,OCTPNT
MOVEI TAC,[ASCIZ /, else type any character. /]
PUSHJ P,CONMES
PUSHJ P,CRLF
PUSHJ P,OPOUT ;DUMP CTY BUFFER ONTO THE CTY
P1G1: SKIPE P2NUM ;WAIT FOR P2 TO START
JRST P2OK ;P2 HAS BEEN STARTED OK.
PUSHJ P,CTGETC ;LOOK FOR TYPEIN.
JRST P1G1 ;NONE.
MOVEI TAC,P2XFR+1 ;MAKE SURE NO ONE STARTS P2 NOW
HRRM TAC,P2XFR1
MOVE TAC,[JRST 4,SYSDSP+4]
MOVEM TAC,(TAC) ;EVEN FROM HERE
IFL PRCONF-2,<
MOVEM TAC,40 ;ZAP P2'S TRAP LOCATIONS
MOVE DAT,[40,,41]
BLT DAT,61 ;NORMALLY A NO-NO BUT INTS OFF HERE
>;P2 IS A PDP-6
IFE PRCONF-2,<
MOVEM TAC,140 ;ZAP P2'S TRAP LOCATIONS
MOVE DAT,[140,,141]
BLT DAT,161 ;NORMALLY A NO-NO BUT INTS OFF HERE
>;P2 IS A KA10
MOVE DAT,LINEP
PUSHJ P,CRLF ;ACKNOWLEDGE RECEIPT OF THE C.R.
PUSHJ P,OPOUT
SETOM DETFLG ;TELLS SYSINI TO DETACH XGP,DAC
ONEP: PUSHJ P,DATIME ;DO WE HAVE THE CRK?
JRST TBAD ;NO, GET TIME FROM OPERATOR
JRST P2OK1
P2OK: MOVE J,CRKTIM ;DOES P2 HAVE CRK?
SKIPN DAT,CRKDAT
JRST TBAD ;NO, GET TIME FROM OPERATOR
P2OK1: MOVEM J,TIME
MOVEM DAT,THSDAT
JRST TOKNOW
TBAD:
IFKL10,<
PUSHJ P,VENTIM ;READ 11'S TIMEBASE
JRST TBAD1
MOVEM ITEM,TIME ;STORE TIME
MOVEM DAT,THSDAT
HRLZM DAT,TIMDAT
MOVE TAC,TIME
IDIVI TAC,JIFSEC
HRRM TAC,TIMDAT ;<DATE>,,<TIME IN SECONDS> FOR DAYT2
MOVE DAT,LINEP ;TELL OPERATOR WHAT WE DID
MOVEI TAC,[ASCIZ /PDP-11 timebase is /]
PUSHJ P,CONMES
PUSHJ P,DAYT2 ;IN CLKSER
MOVEI TAC,[ASCIZ /Type Y if this is ok: /]
PUSHJ P,CONMES
PUSHJ P,OPOUT ;DUMP CTY BUFFER ONTO THE CTY
PUSHJ P,CTGETC ;LOOK FOR TYPEIN.
JRST .-1 ;NONE.
PUSH P,TAC ;SAVE CHARACTER
PUSHJ P,CTPUTC ;ECHO THE CHARACTER
MOVE DAT,LINEP
PUSHJ P,CRLF
PUSHJ P,OPOUT
POP P,TAC
CAIE TAC,"Y"
CAIN TAC,"Y"+40
JRST ONCE9 ;HE LIKED IT
>;IFKL10
TBAD1: PUSHJ P,DATLOP
PUSHJ P,TIMLOP
TOKNOW:
IFKL10,<
MOVE TAC,THSDAT
PUSHJ P,DAYCNT ;CONVERT TO DAY COUNT
MUL TAC,[=24*=3600*JIFSEC] ;TIMES JIFFIES PER DAY
MOVEI AC1,0
MOVE AC2,TIME
DADD TAC,AC1
DMOVEM TAC,KLTIME
PUSHJ P,STIMBS ;SET PDP-11'S TIMEBASE
>;IFKL10
ONCE9: MOVSI TAC,(<JFCL>)
MOVEM TAC,ONCEI
IFN 0*FTDISK,<
DATAI APR,TAC ;-1 IN KEYS GETS YOU
AOJN TAC,LINKSR ;THE REFRESH DIALOG.
PUSHJ P,REF
>;IFN 0*FTDISK
JRST LINKSR
;HERE IS WHERE P2 STARTS
;WE MUST DECIDE IF THIS IS A LEGAL CONFIGURATION OR NOT
0 ;JSR HERE TO ENTER EXEC MODE
↑P2START:
CONO APR,200000 ;RESET CPU
MOVE P,[-P2PLN,,P2PDL-1]
SKIPP2
JRST SYSDSP
MOVE TAC,[JRST P2INI] ;TELL SYSTEM WE HAVE INITIALIZED
MOVEM TAC,SYSDSP+4
SKIPN P1NUM
JRST .-1 ;WAIT FOR P1 TO START UP
CONSZ APR,MAOFF ;KA10 MUST BE IN MAOFF MODE
JRST MAOFON
MOVE TAC,[440700,,[ASCIZ /
TURN ON MA TRAP OFFSET!!
/]]
JSR DDTTYPE
CONSO APR,MAOFF
JRST .-1
MAOFON: MOVEI TAC,140
MOVEM TAC,UUOLOC+P2PID
MOVSI TAC1,P2LOC40
HRRI TAC1,(TAC)
BLT TAC1,21(TAC) ;SET UP INTERRUPT LOCATIONS
IFN FTPAGER,<
MOVE TAC,P2GLOC
MOVEM TAC,P2PAGT ;SET UP 170 AND ...
MOVE TAC,[P2GLOC+1,,P2PAG] ;... 71 AND 72
BLT TAC,P2PAG1
>;IFN FTPAGER
IFLE PRCONF-1,< MOVEI TAC,132237 ;166 PI ENB CHN 3-7, PAR ENB, CLR PAR ERR>
IFE PRCONF-2,< MOVEI TAC,652237 ;KA10 PI ENB PAR, CHNS, CLR ERRORS>
HRRM TAC,P2CON
MOVE TAC,[ALTSAV,,PTPSAV]
BLT TAC,ALTSAV-1 ;SET UP DEVICE AC SAVE INDIRECT LOCATIONS
PUSHJ P,DATIME ;SEE IF CRK WORKS
JRST P2GO1 ;NO, SKIP IT
MOVEM DAT,CRKDAT ;YES, SET STARTING DATE
MOVEM ITEM,CRKTIM
P2GO1: SETOM P2NUM ;ANNOUNCE THAT P2 IS ALIVE
JRST P2XFR1
;DATLOP, TIMLOP GET DATE AND TIME FROM CTY
;ASK FOR TODAY'S DATE AND CONVERT
;DATE STORED AS ((Y-64)*12.+M-1)*31.+D-1
DATLOP: MOVE DAT,LINEP
MOVEI TAC,TODATE
PUSHJ P,CONMES
PUSHJ P,OPOUT
PUSHJ P,GETLIN
JRST DATLOP
PUSH P,TAC ;SAVE INPUT BYTE POINTER
MOVEI IOS,11 ;STORE DATE TYPED IN ON TOP OF DATE OF SYSTEM
MOVE ITEM,DATPTR ;MAX. OF 11 CHAR. INCL. CR
ILDB TAC1,TAC ;CLOBBER SYSDAT
IDPB TAC1,ITEM
CAIE TAC1,15
SOJG IOS,.-3
JUMPLE IOS,DATLOP ;TOO MANY CHARS?
MOVEI TAC1,0 ;STORE NULL ON TOP OF CR
DPB TAC1,ITEM
POP P,TAC ;RESTORE INPUT BYTE POINTER
PUSHJ P,DECIN ;MONTH
JRST DATLOP ;ERROR
SKIPE TAC1
CAILE TAC1,=12
JRST DATLOP
SUBI TAC1,1
IMULI TAC1,=31
MOVEM TAC1,THSDAT
PUSHJ P,DECIN ;DAY
JRST DATLOP
SKIPE TAC1
CAILE TAC1,=31
JRST DATLOP
SUBI TAC1,1
ADDM TAC1,THSDAT
PUSHJ P,DECIN ;YEAR
JRST DATLOP
CAIL TAC1,=76
CAILE TAC1,=99
JRST DATLOP
SUBI TAC1,=64 ;YEAR ZERO
IMULI TAC1,=12*=31
ADDM TAC1,THSDAT
POPJ P,
TIMLOP: SETZM TIME ;GET TIME OF DAY
MOVE DAT,LINEP
MOVEI TAC,TIMEM
PUSHJ P,CONMES
PUSHJ P,OPOUT
PUSHJ P,GETLIN
JRST TIMLOP ;JUST A CR
PUSHJ P,DECIN
JRST TIMLOP
MOVE TAC,TAC1
IDIVI TAC,=100 ;HOURS IN TAC, MINUTES IN TAC1
CAIGE TAC,=24 ;ERROR (SKIP) IF HOURS EXCEED 23
CAILE TAC1,=59 ;ERROR (NO SKIP) IF MINUTES EXCEED 59
JRST TIMLOP
IMULI TAC,=60
ADD TAC,TAC1 ;TAC←NUMBER OF MINUTES PAST MIDNIGHT.
IMULI TAC,JIFSEC*=60 ;CONVERT MINUTES TO JIFFIES
MOVEM TAC,TIME
POPJ P,
;;DECIMAL INPUT ROUTINE - JAM
DECIN: ILDB TAC1,TAC ;FIRST, SKIP NULLS, SPACES, AND TABS
JUMPE TAC1,DECIN
CAIE TAC1," "
CAIN TAC1,11
JRST DECIN
CAIG TAC1,"9"
CAIGE TAC1,"0"
POPJ P,
SUBI TAC1,"0"
DECIN1: ILDB AC1,TAC
CAIE AC1,"-"
CAIN AC1,"/"
JRST CPOPJ1
CAIE AC1,15
CAIN AC1,12
JRST CPOPJ1
CAIG AC1,"9"
CAIGE AC1,"0"
POPJ P,
SUBI AC1,"0"
IMULI TAC1,=10
ADD TAC1,AC1
JRST DECIN1
IFN 0*FTDISK,< ;REFRESH DIALOGUE
REF: MOVE DAT,LINEP ;DO YOU WANT TO REFRESH?
MOVEI TAC,REF1M
PUSHJ P,CONMES
PUSHJ P,OPOUT
PUSHJ P,GETLIN
POPJ P, ;NO
ILDB DAT,TAC ;GET FIRST CHAR
CAIE DAT,"Y" ;Y?
POPJ P, ;NO. DONT REFRESH THE DISK
MOVE DAT,LINEP ;YES. ARE YOU SURE?
MOVEI TAC,REF2M
PUSHJ P,CONMES
PUSHJ P,OPOUT
PUSHJ P,GETLIN
POPJ P, ;NO
ILDB DAT,TAC
CAIE DAT,"Y"
POPJ P,
REF3: PUSHJ P,REFRES ;REFRESH.
MOVE DAT,LINEP ;OK
MOVEI TAC,REF6M
PUSHJ P,CONMES
PUSHJ P,OPOUT
MOVE TAC,DUMPPN ;DEC 3.16
MOVEM TAC,REFLAG
POPJ P,
REF1M: ASCIZ /DO YOU WANT TO REFRESH THE DISK?
/
REF2M: ASCIZ /DO YOU REALLY WANT TO REFRESH?
/
REF6M: ASCIZ /REFRESHED! FIRST JOB TO LOG IN GETS IN FREE.
/
>
;ROUTINE TO READ A LINE FROM OPERATORS CONSOLE
;CALL: PUSHJ P,GETLIN
; JUST A CR TYPED IN
; A LINE TYPED IN,TAC SET AS BYTE POINTER
CHREC←TEM ;CHAR TO TYPE OUT(MUST BE SAME AS SCNSER ROUTINE
LINE←TAC1 ;TTY LINE NO.(ALSO SAME AS SCNSER)
GETLIN: MOVE TAC,LINEP
MOVEI ITEM,0
GET1: PUSHJ P,TYI
CAIN TAC1,177 ;RUBOUT?
JRST DELETE
MOVE CHREC,TAC1 ;NO, ECHO CHAR.
PUSHJ P,TYO
IDPB TAC1,TAC ;AND STORE CHAR.
CAIE TAC1,15
AOJA ITEM,GET1
MOVEI CHREC,12 ;OUTPUT LF
PUSHJ P,TYO ;TYPE OUT
MOVE TAC,LINEP ;RESET BYTE POINTER
JUMPN ITEM,CPOPJ1 ;NULL LINE?
POPJ P, ;YES, DON'T SKIP RETURN
DELETE: JUMPE ITEM,DELET1 ;AT BEGINNING OF LINE?
ADD TAC,[XWD 070000,0] ;NO, BACK UP BYTE POINTER
TLNE TAC,400000 ;FINISHED THIS WORD YET?
ADD TAC,[XWD 347777,-1] ;YES, BACK UP ADDRESS
MOVEI CHREC,134 ;OUTPUT BACK SLASH
PUSHJ P,TYO
SOJA ITEM,GET1
DELET1: MOVEI CHREC,15
PUSHJ P,TYO
MOVEI CHREC,12
PUSHJ P,TYO
JRST GETLIN
;ROUTINE TO TYPE A LINE ON OPERATOR CONSOLE
;ECHO CHECK STOPS LINE AND RETURNS
;CALL: DAT SET TO END OF MESSAGE
OPOUT: PUSHJ P,CTGETC ;READ CHARACTER TO CLEAR INPUT, IF ANY
JFCL ;IGNORE
MOVE TAC,LINEP
OPOUT1: CAMN TAC,DAT
POPJ P,
PUSH P,TAC
PUSHJ P,CTGETC ;DID OPR TYPE ANYTHING?
JRST OPOUT2 ;NO.
SUB P,[1,,1] ;YES. ADJUST STACK
MOVEI CHREC,15
PUSHJ P,TYO
MOVEI CHREC,12
TYO: PUSH P,TAC
MOVE TAC,CHREC
PUSHJ P,CTPUTC
JRST TPOPJ
OPOUT2: ILDB CHREC,(P) ;GET NEXT CHARACTER
PUSHJ P,TYO
POP P,TAC
JRST OPOUT1
;WAIT FOR CHARACTER. RETURN IT IN TAC1
TYI: PUSH P,TAC
PUSHJ P,CTGETC ;GET A CHARACTER
JRST .-1 ;NONE THERE YET. TRY AGAIN
MOVE TAC1,TAC
JRST TPOPJ
;CONSTANTS AND PUSH DOWN LIST
LINEP: POINT 7,LINBUF ;INPUT AND OUTPUT LINE BUFFER
LINBUF: BLOCK 30
ONCEPN←←100
ONCEPD: BLOCK ONCEPN ;PUSH DOWN LIST
P2PLN←←100
P2PDL: BLOCK P2PLN
SYSDAT: BLOCK 2
;MESSAGES
TODATE: ASCIZ /
Type today's date as mm-dd-yy
/
DATPTR: POINT 7,SYSDAT ;POINTER TO SYSTEM DATE
TIMEM: ASCIZ /
Enter time of day in 24-hour format
/
IFE FTDDT,<
NDDTM: ASCIZ/NON-DDT SYSTEM!
/
>
IFKL10,< ;LOAD CACHE REFILL ALGORITHM
SETCRA: CONSZ KLPAG,600000 ;SKIP IF CACHE IS OFF
POPJ P,
MOVEI TAC,405 ;READ CLOCK DEFAULT WORD
PUSHJ P,DTEXX
LDB TAC,[POINT 4,TAC,3] ;GET THE CACHE ENABLE CODE FROM THE 11
PUSH P,TAC
MOVEI TAC,[ASCIZ /Cache enables = /]
PUSHJ P,CONMES
MOVE TAC,(P)
PUSHJ P,OCTPNT
PUSHJ P,CRLF
POP P,TAC
JUMPE TAC,CPOPJ
MOVEI 0,0
MOVE AC2,[ILDB TAC,TAC1] ;LOAD DATA UNLESS ENABLING ONLY 1 CACHE
SKIPL TAC1,CPTAB(TAC) ;TAC1←BYTE POINTER TO DATA
MOVE AC2,[MOVE TAC,TAC1] ;ONLY 1 CACHE. TAC1 IS DATA NOT BYTE POINTER
CRA.1: XCT AC2 ;GET DATUM
DPB TAC,[POINT 3,0,20] ;STORE IN BITS 18:20
BLKO APR,@0 ;SEND DATA.
ADDI 0,4 ;ADVANCE RAM ADDRESS IN BITS 27:33
TRNN 0,1000 ;IF ADDRESS EXCEEDS =128 WE'RE DONE. (1B26)
JRST CRA.1 ;LOOP
POPJ P,
;BYTE POINTERS TO THE CACHE RELOAD PROGRAMS FOR ALL POSSIBLE
;CONFIGURATIONS OF THE CACHE (ENCODED AS 0-17). FOR THES SPECIAL
;CASES OF ONLY ONE CACHE ENABLED, THE TABLE CONTAINS THE DATA RATHER
;THAN A BYTE POINTER.
;10=CACHE 0
; 4=CACHE 1
; 2=CACHE 2
; 1=CACHE 3
CPTAB: 0
3 ;3
2 ;2
440300,,CPT.03
1 ;1
440300,,CPT.05
440300,,CPT.06
440300,,CPT.07
0 ;0
440300,,CPT.11
440300,,CPT.12
440300,,CPT.13
440300,,CPT.14
440300,,CPT.15
440300,,CPT.16
440300,,CPT.17
CPT.17: 012345673123 ;0123
212371271127
656755670323
022301234567
077700074666
446431331113
077700070123
456745574547
012201210566
056045654564
012345670000
CPT.16: 012245612122 ;012
212211211121
656255620626
022601264560
000000004666
446451551115
044400040125
456445504540
012201210566
056045654564
012645640000
CPT.15: 013345173133 ;013
313371371137
151755170373
077301734507
077700074000
440431331113
077700070173
450745574547
015501510544
054045454544
015345470000
CPT.13: 032342673323 ;023
232373273327
626722670323
022307234067
077700074666
446437337773
077700070723
406740074047
062206260466
046044644464
062344670000
CPT.07: 312315673123 ;123
212371271127
656755677323
722331232567
377733372666
226231331113
777777777123
156715571517
512251216566
656655655565
612355670000
CPT.14: 015545115155 ;01
515511411141
151455140444
044401444500
000000004000
440451551115
044400040145
450445504540
015501510544
054045454544
015445440000
CPT.12: 062242662422 ;02
242266266626
626222620626
022604264060
000000004666
446444444444
044400040424
406440004040
062206260466
046044644464
062644640000
CPT.11: 033347773333 ;03
333373373337
777777770373
077307734007
077700074000
440437337773
077700070773
400740074047
044404440444
044044444444
044344470000
CPT.06: 512215612122 ;12
212211211121
656255621626
122661262566
666666662666
226251551115
555555555125
156515521512
512251216566
656655655565
612655660000
CPT.05: 313315173133 ;13
313371371137
151755177373
777331737577
377733377777
777731331113
777777777173
157715571517
515551515555
555555355535
515355570000
CPT.03: 332372673323 ;23
232373273327
626722677323
722337232767
377733372666
226237337773
777777777723
776777777777
362236266366
636666666666
662366670000
>;IFKL10
;206 RESTARTS -- USER AND EXEC MODE
PRINTX 206 RESTART CODE IS THOROUGHLY BROKEN
BEGERR: SETZM SYSTHERE ;SYSTEM'S NOT ON L'SCOPE
NOKL10,< DATAO CTY,[7] ;DING FOR HIM >
IFN FTDSWP,< SETZM DDTSUM
SETZM SYMLOC ;NO SWAPPING DDT YET>
HALT BEGIN
↑BEGIN: SETOM SYSTHERE ;SET TO SAY SYSTEM IS ON LIBRASCOPE
MOVE P,[-ERRPLN,,ERRPDL-1] ;GET A PDL
JSP TAC,.+1 ;206 START: WRITE OUT SYSTEM.
TLNE TAC,USRMOD ;ARE WE IN USER MODE?
JRST USBG1 ;USER MODE, SPECIAL HACK.
CONO APR,200000 ;RESET THE WORLD
NOKL10,<
PUSHJ P,FMCHK ;MAKE SURE WE HAVE FAST AC'S
JRST BEGIN ;NO. LOOK AGAIN.
>;NOKL10
IFKL10,< ;ASSMBLE FOR KL10 BASED SYSTEMS
CONSZ APR,SWEEPB ;WAIT FOR SWEEP BUSY TO FALL
JRST .-1
CONSO KLPAG,600000 ;IS THE CACHE ON ALREADY?
JRST BEG.I1 ;NO.
BLKO CCA, ;VALIDATE CORE
CONSZ APR,SWEEPB
JRST .-1
BEG.I1: CONO KLPAG,0 ;NO CACHE, MAP. EBR TO 0.
MOVEI TAC,KLEPT ;PHYSICAL ADDRESS OF THE KL10'S EPT
LSH TAC,-=9 ;CONVERT TO PAGE NUMBER
CONO KLPAG,(TAC) ;SET EBR, NO CACHE, NO MAP
>;IFKL10
CONSZ DSK,400 ; IS THE DISK ON-LINE?
JRST BEGERR ; NO, EXIT NOW.
IFN FTDSWP,<
SKIPA TAC,DDTSYM ;DDTSYM=36 SET BY TENDMP
USBG1: MOVE TAC,JOBSYM ;IN USER MODE, USE JOBSYM
MOVEM TAC,SYMLOC
MOVE TAC,[XWD DDTA-DDTEND,DDTA] ;GET IOWD FOR CHECKSUM
PUSHJ P,CHECK ;MAKE A CHECKSUM
MOVEM TAC1,DDTSUM ;SAVE DDT CHECKSUM
>
IFE FTDSWP,<
USBG1: >
MOVE TAC,[JRST 4,203] ;SET UP LOCATION 206
MOVEM TAC,SYSDSP+6 ;STUFF SYSTEM INITIALIZATION ADDRESS
JSP TAC,.+1
TLNE TAC,USRMOD ;USER MODE?
JRST USRBEG ;YES. GO OFF AND FAKE IT.
MOVE TAC,[LOD20,,20]
BLT TAC,27 ;MAKE SURE 20 LOADER IS GOOD
MOVSI AC1,-=76*2000 ;ALL OF LOWER CORE.
MOVE TAC,SYSBAND
PUSHJ P,USXBG
JRST BEGERR ;LOSE
PUSHJ P,BGSYMC ;FIGURE OUT WHERE SYMBOLS GO ON DDTBAND
JRST SYSDSP ;NO SYMBOLS, JUST START UP SYSTEM.
ANDCMI AC1,37 ;AC1←SYMLOC BY BGSYMC
ADD AC1,[-40,,0]
MOVE TAC,AC3 ;SECTOR ON DDTBAND WHERE SYMBOLS GO
CAIL TAC,2300 ;NEXT TRACK?
ADDI TAC,1B24-2300 ;NEXT TRACK IF SECTOR ≥ 2300
ADD TAC,DDTBAND
PUSHJ P,USXBG ;WRITE SYMBOLS
JRST BEGERR
JRST SYSDSP
;USXBG WRITE ON LSCOPE USING AC1 AS AOBJN PTR, TAC AS BAND DATAO
;SKIP RETURN UNLESS THERE IS AN ERROR
USXBG: CONO IOP,100 ;SET UP IOP FOR WRITING.
DATAO IOP,AC1 ;AOBJN POINTER TO TRANSFER
DATAO DSK,TAC ;BAND TO WRITE ON
CONSO IOP,IOPANY!IOPJDN ;WAIT UNTIL DONE.
JRST .-1
CONSO IOP,IOPANY ;ERRORS?
CONSZ DSK,3370 ;ERRORS?
POPJ P,
JRST CPOPJ1
;HERE IF USER SAYS
;GET SYSTEM
;S 206
USRBEG: RESET
MOVNI TAC,1
SETPRV TAC, ;SETPRV - GET CURRENT PRIVILEGES.
TLON TAC,PRIPRV+FBWPRV ;HAVE WE GOT PRIVILEGE?
HALT USRBEG
SETPRV TAC, ;GET IT.
MOVEI AC1,140 ;FIRST ADDRESS TO WRITE.
MOVE TAC,SYSBND ;GET THE SYSTEM BAND.
TRO TAC,400000 ;MAKE IT ABSOLUTE.
SKIPN AC2,SYMLOC ;START OF SYMBOL TABLE
JRST [HRRZ AC2,JOBREL
SUBI AC2,137
JRST USRBG1 ]
MOVEI AC2,-140(AC2) ;LESS OFFSET, LEAVES WORD COUNT
USRBG1: MOVEI AC3,3 ;START IN SECTOR 3 TO ACCOUNT FOR
;OFFSET.
FBWRT TAC,AC1 ;ASK SYSTEM TO WRITE THIS.
OUTSTR [ASCIZ /FBERROR SYSTEM WRITE
/]
MOVEI AC2,=76*2000 ;THIS IS THE SIZE OF AN L'SCOPE BAND
SKIPN AC3,SYMLOC
JRST [HRRZ AC3,JOBREL
AOJA AC3,USRBG2] ;AC3 HAS FIRST LOCATION TO ZERO FROM
ADDI AC3,37
USRBG2: ANDI AC3,777740 ;AC3 HAS FIRST LOCATION TO ZERO FROM
SUBI AC2,(AC3) ;THIS IS THE SIZE OF NEXT XFER
JUMPE AC2,BEGUX ;JUMP IF THERE'S NO SPACE TO FILL UP
LSH AC3,-5 ;COMPUTE SECTOR
FBWRT TAC,AC1 ;MAKE SURE ENTIRE BAND IS READABLE
OUTSTR [ASCIZ /FBERROR CLEARING BAND
/]
BEGUX: MOVEI AC2,101 ;(PAD TO 137 WITH ZEROES)
MOVEI AC3,0 ;SECTOR
MOVEI AC1,LODTAB ;PLACE TO START.
MOVE TAC1,JOBSYM
MOVEM TAC1,LODSYM ;SAVE CYMBALS
MOVE TAC1,JOBREL
MOVEM TAC1,LODREL ;SAVE JOBREL
FBWRT TAC,AC1
OUTSTR [ASCIZ /FBERROR LOW CORE WRITE
/]
PUSHJ P,BGSYMC ;CALCULATE WHERE TO PUT SYMBOLS
EXIT ;NO SYMBOLS
MOVEI AC2,40(AC2) ;AMOUNT TO TRANSFER
ANDI AC1,777740 ;START WRITING FROM JUST BEFORE SYMBOLS
MOVE TAC,JOBREL ;LAST ADDRESS IN CORE
SUBI TAC,-1(AC1) ;-STARTING ADDRESS+1 = MAX WORD COUNT
CAILE AC2,(TAC)
MOVEI AC2,(TAC) ;ADJUST TO MAKE A SMALLER TRANSFER
MOVE TAC,DDTBND
IORI TAC,400000 ;MAKE IT ABSOLUTE
FBWRT TAC,AC1 ;WRITE OUT SYMBOLS ON DDTBAND
OUTSTR [ASCIZ /FBERROR WRITING SYMBOLS ON DDTBAND
/]
EXIT
;PUNCH SYSTEM LOADER WITH CURRENT LOC OF SYSTEM ON LIBRASCOPE
↑SYSLOD:
MOVE 1,SYSBAND
MOVEM 1,LODTAB+SBAND ;GET BAND DYNAMICALLY
JSP 2,FEED
CONSZ PTP,20
JRST .-1
CONO PTP,50 ;CLEAR PAPER TAPE PUNCH AND SET BINARY MODE
SKIPA 1,[-LODLEN,,LODTAB]
PUNXT0: TDZA 2,2
PUNNXT: MOVE 2,(1)
MOVEI 3,6
PUN1: ROT 2,6
CONSZ PTP,20
JRST .-1
DATAO PTP,2
SOJG 3,PUN1
AOBJN 1,PUNNXT
TLNN 1,-1
JRST PUNXT0 ;PUNCH EXTRA WORD OF ZERO TO STOP PTR ON READIN
JSP 2,FEED
HALT SYSLOD
FEED: MOVEI 1,=100
FEED1: CONSZ PTP,20
JRST FEED1
CONO PTP,10
DATAO PTP,[0]
SOJG 1,FEED1
JRST (2)
LODTAB: XWD -LODLEN+1,0
PHASE 1
LODIT: MOVE BLTAC ;1 THIS IS LOC 20 BE CAREFUL
SETZM 20 ;2
BLT 377777 ;3
LODLUP: DATAO IOP,SLOC ;4
DATAO DSK,SBAND ;5
CONSO IOP,IOPANY!IOPJDN ;6
JRST .-1 ;7
CONSO IOP,IOPANY ;10
CONSZ DSK,3370 ;11
HALT LODLUP ;12
JRST SYSDSP ;13
SLOC: XWD -=76*2000,0 ;14
SBAND: 100B23 ;15 REALLY TO BE FILLED IN BY SYSLOD
BLTAC: 20,,21 ;16
JRST LODIT ;17 TO START IT
DEPHASE
LODLEN←←.-LODTAB
BLOCK 20-LODLEN ;BLOCK UP TO BOUNDARY, IF NEEDED.
LOD20: CONO PTR,60 ;20 LOADER
CONSO PTR,10
JRST 21
DATAI PTR,26
CONSO PTR,10
JRST 24
0
JRST 21
BLOCK 6 ;GET TO 36
LODSYM: 0
LODREL: 0
BLOCK 41 ;PAD TO AT LEAST 101 WORDS FROM LODTAB
;START - USER MODE 200 STARTUP
DEFINE NPRINT(TAG,START,FINISH)
< OUTSTR [ASCIZ/
TAG/]
MOVEI TAC,FINISH-START
PUSHJ P,DECOUT
>
DEFINE QPRINT(TAG,START,FINISH,S2,F2)
< OUTSTR [ASCIZ/
TAG/]
MOVEI TAC,FINISH-START
PUSHJ P,DECOUT
IFN FTHSYS,<
OUTCHR ["+"]
MOVEI TAC,F2-S2
PUSHJ P,DECOUT
>
>
DECOUT: IDIVI TAC,=10
HRLM TAC1,(P)
JUMPE TAC,.+2
PUSHJ P,DECOUT
HLRZ TAC,(P)
ADDI TAC,60
OUTCHR TAC
POPJ P,
↑START: MOVE P,[IOWD 20,SPDL] ;FOR USE WITH DUMP COPY OF SYSTEM
OUTSTR CONFIG ;SYSTEM NAME
NPRINT <Impure part >,0,CHKBEG
QPRINT <System stuff >,CHKBEG,DEVBEG,HIBEG,HIDVBG
QPRINT <Device Service >,DEVBEG,CHKEND,HIDVBG,HIEND
NPRINT <DDT >,CHKEND,BLTBEG
NPRINT <ONCE >,BLTBEG,THEEND
HLRO TAC,116 ;JOBSYM
MOVNS TAC
OUTSTR [ASCIZ/
Symbols /]
PUSHJ P,DECOUT
QPRINT <With DDT out >,0,DDTA,HIBEG,HIEND
CALLI 12
SPDL: BLOCK 20
LIT↔VAR
THEEND:
BEND ONCE
END SYSDSP